//
           Title: Simon Says
            Name: SIMON
         Version: v2.1
          Author: Bungeman (Ben Wagner)
           Email: bungeman@juno.com
         Webpage: http://members.tripod.com/~bungeman/casio
	   Model: 9850, 9950
     Description: My second Casio program. It took me a while to
                  get it the way I wanted. The calc shows its
                  numbers one at a time as you hit EXE. Then repeat
                  them back by hitting the numbers on the keypad.
//

[[1,1,1,1,1,1,1,1,1]]->Mat N	'Setup matrix
For 1->I To 9
Int (9Ran#+1)->Mat N[1,I]
Next
1->T				'Initialize
0->B
Do
 ClrText			'Display comp #s
 "SIMON SAYS"
 "COMP#"
 For 1->I To T
  Mat N[1,I]->Z
  Locate 7,2,Z_
 Next
 ClrText
 "Your#"?->Y
 For 1->I To T			'Ask for yours
  0->Y
  Do
   Getkey->K
  LpWhile K>0
  Do
   Getkey->K
   K>50=>(4-(Int (K/10)-4))+((Frac (K/10)*10-2)*3)->Y
  LpWhile Y<1 Or Y>9
  Locate 7,1,Y
  Mat N[1,I]->Z			'See if it matches
  If (Y=Z) And (I=T)
   Then T+1->T:100->I
  IfEnd
  If Y<>Z
   Then B+1->B:100->I
   "THAT WAS THE WRONG"
   "NUMBER!"/
  IfEnd
 Next
LpWhile (B<>3) And (T<>10)
[[0]]->Mat N			'Delete matrix
If B=3				'Display outcome
 Then "HA HA I BEAT YOU."
 Else "YOU DID IT, YOU WIN."
IfEnd